tuto:ipasserelle:divers:scripts_dokuwiki

Ceci est une ancienne révision du document !


Scripts pour dokuwiki

Voilà quelques scripts qui permettent de générer des tableaux au format dokuwiki:

  • Génère un tableau de tous les dossiers partagés (uniquement via la contrib smeserver-shared-folders), avec la liste des groupes ayant accès en lecture ou en écriture
shares.pl
#!/usr/bin/perl -w
 
use strict;
use esmith::AccountsDB;
 
my $a = esmith::AccountsDB->open_ro() || die "Couldn't open the accounts database";
 
print "^ Nom ^ Acces en ecriture ^  Acces en lecture seule ^  Acces au reseau local ^ Acces web ^ Remarque ^\n";
 
foreach my $share ($a->get_all_by_prop(type => 'share')) {
    my $name = $share->key;
    my $w = join " ", split (/,/, ($share->prop('WriteGroups') || ''). ',' . ($share->prop('WriteUsers') || ''));
    my $r = join " ", split (/,/, ($share->prop('ReadGroups') || '') . ',' . ($share->prop('ReadUsers') || ''));
    my $loc = (($share->prop('smbAccess') || 'none') ne 'none') ? 'Oui':'Non';
    my $remote = $share->prop('httpAccess') || 'none';
    my $rem = '';
    if ($remote eq 'global'){
        $rem = 'public sans mot de passe';
    }
    elsif ($remote eq 'local'){
        $rem = 'depuis les réseau locaux uniquement, sans mot de passe';
    }
    elsif ($remote eq 'local-pw'){
        $rem = 'depuis les réseaux locaux uniquement, authentification nécessaire'
    }
    elsif ($remote eq 'global-pw'){
        $rem = 'public, authentification nécessaire';
    }
    elsif ($remote eq 'global-pw-remote'){
        $rem = 'public, authentification nécessaire depuis l\'exterieur';
    }
    elsif ($remote eq 'none'){
        $rem = 'Non';
    }
    my $com = '';
    if ($name eq 'intranet'){
        $com = "Partage réservé à un usage interne";
    }
    elsif ($name eq 'extranet'){
        $com = "Partage public vers l'extérieur";
    }
    elsif ($name eq 'tools'){
        $com = "Partage utilisé pour les tâches administratives";
    }
    elsif ($name eq 'wpkg' or $name eq 'wpkglogs'){
        $com = "Partage utilisé pour le déploiement de logiciels";
    }
    print '|' . $name . ' |' . $w . ' |' . $r . ' |' . $loc . ' |' . $rem . ' |' . $com . ' |' . "\n";
}
  • Génère une matrice des groupes et des utilisateurs, avec affichage des appartenance aux groupes
groups.pl
#!/usr/bin/perl -w
 
use strict;
use esmith::AccountsDB;
 
my $a = esmith::AccountsDB->open_ro() || die "Couldn't open the accounts database";
 
my @groups = $a->groups;
my @users = $a->users;
 
# Print the header
print '|  ';
print "^ " . $_->key foreach (@groups);
print ' ^' . "\n";
 
foreach my $user (@users){
    my $pos = 0;
    print '|' . $user->key . '|';
    foreach my $group (@groups){
        print 'x' if ($a->is_user_in_group($user->key,$group->key));
        print ' |';
    }
    print "\n";
}
  • Génère un tableau des pseudonymes
pseudo.pl
#!/usr/bin/perl -w
 
use strict;
use esmith::AccountsDB;
 
my $a = esmith::AccountsDB->open_ro() || die "Couldn't open the accounts database";
 
print '^ Pseudonyme ^ Utilisateur ou groupe ^' . "\n";
 
print '|' . $_->key . ' |' . $_->prop('Account') . " |\n" foreach ($a->get_all_by_prop (type => "pseudonym"));
  • tuto/ipasserelle/divers/scripts_dokuwiki.1386238174.txt.gz
  • Dernière modification: 05/12/2013 11:09
  • de dani